Galactica/crates/render/shaders/ui.wgsl

// INCLUDE: global uniform header

struct InstanceInput {
	@location(2) anchor: u32,
	@location(3) position: vec2<f32>,
	@location(4) angle: f32,
	@location(5) size: f32,
	@location(6) color_transform: vec4<f32>,
	@location(7) texture_index: vec2<u32>,
	@location(8) texture_fade: f32,
	@location(9) mask_index: vec2<u32>,
};

struct VertexInput {
	@location(0) position: vec3<f32>,
	@location(1) texture_coords: vec2<f32>,
}

struct VertexOutput {
	@builtin(position) position: vec4<f32>,
	@location(0) texture_coords: vec2<f32>,
	@location(1) texture_index: u32,
	@location(2) mask_coords: vec2<f32>,
	@location(3) mask_index: vec2<u32>,
	@location(4) color_transform: vec4<f32>,
}

@group(0) @binding(0)
var texture_array: binding_array<texture_2d<f32>>;
@group(0) @binding(1)
var sampler_array: binding_array<sampler>;


// INCLUDE: anchor.wgsl


fn transform_vertex(
	instance: InstanceInput,
	vertex_position: vec3<f32>,
	texture_index: u32,
) -> vec4<f32> {
	
	let window_dim = global_data.window_size / global_data.window_scale.x;
	let scale = instance.size / window_dim.y;
	let aspect = (
		global_atlas[instance.texture_index.x].width /
		global_atlas[instance.texture_index.x].height
	);

	// Apply scale and sprite aspect
	// Note that our mesh starts centered at (0, 0). This is important!
	var pos: vec2<f32> = vec2(
		vertex_position.x * scale * aspect,
		vertex_position.y * scale
	);

	// Apply rotation (and adjust sprite angle, since sprites point north)
	pos = mat2x2(
		vec2(cos(instance.angle - 1.5708), sin(instance.angle - 1.5708)),
		vec2(-sin(instance.angle - 1.5708), cos(instance.angle - 1.5708))
	) * pos;

	// Correct for screen aspect, preserving height
	pos = vec2(
		pos.x / global_data.window_aspect.x,
		pos.y
	);

	pos = pos + anchor(
		instance.anchor,
		instance.position,
		vec2(instance.size * aspect, instance.size)
	);

	return vec4<f32>(pos, 0.0, 1.0);
}

@vertex
fn vertex_main(
	vertex: VertexInput,
	instance: InstanceInput,
) -> VertexOutput {

	// TODO: this will break if we try to use texture 0.
	// implement animations for ui sprites & fix that here.

	let pos = transform_vertex(
		instance,
		vertex.position,
		instance.texture_index.x,
	);

	var out: VertexOutput;
	out.position = pos;
	out.color_transform = instance.color_transform;


	// TODO: function to get texture from sprite
	// Pick texture frame
	let t = global_atlas[instance.texture_index.x];
	out.texture_index = u32(t.atlas_texture);
	out.texture_coords = vec2(t.xpos, t.ypos);
	if vertex.texture_coords.x == 1.0 {
		out.texture_coords = vec2(out.texture_coords.x + t.width, out.texture_coords.y);
	}
	if vertex.texture_coords.y == 1.0 {
		out.texture_coords = vec2(out.texture_coords.x, out.texture_coords.y + t.height);
	}

	// Pick mask image if mask is enabled
	// x coordinate of mask index is either 0 or 1, telling us whether or not to use a mask.
	// y coordinate is mask sprite index
	if instance.mask_index.x == 1u {
		let m = global_atlas[instance.mask_index.y];
		out.mask_index = vec2(1u, u32(m.atlas_texture));
		out.mask_coords = vec2(m.xpos, m.ypos);
		if vertex.texture_coords.x == 1.0 {
			out.mask_coords = vec2(out.mask_coords.x + m.width, out.mask_coords.y);
		}
		if vertex.texture_coords.y == 1.0 {
			out.mask_coords = vec2(out.mask_coords.x, out.mask_coords.y + m.height);
		}
	} else {
		out.mask_coords = vec2(0.0, 0.0);
		out.mask_index = vec2(0u, 0u);
	}

	return out;
}


@fragment
fn fragment_main(in: VertexOutput) -> @location(0) vec4<f32> {

	var mask: f32 = 1.0;
	if in.mask_index.x == 1u {
		mask = textureSampleLevel(
			texture_array[in.mask_index.y],
			sampler_array[0],
			in.mask_coords,
			0.0
		).a;
	}

	var color: vec4<f32> = textureSampleLevel(
		texture_array[in.texture_index],
		sampler_array[0],
		in.texture_coords,
		0.0
	).rgba * in.color_transform;

	// Apply mask and discard fully transparent pixels
	color = vec4(color.rgb, color.a *mask);
	if color.a == 0.0 {
		discard;
	}

	return color;
}