Galactica/crates/render/shaders/particle.wgsl

// INCLUDE: global uniform header

struct InstanceInput {
	@location(2) position: vec2<f32>,
	@location(3) velocity: vec2<f32>,
	@location(4) rotation_0: vec2<f32>,
	@location(5) rotation_1: vec2<f32>,
	@location(6) size: f32,
	@location(7) created: f32,
	@location(8) expires: f32,
	@location(9) texture_index: u32,
};

struct VertexInput {
	@location(0) position: vec3<f32>,
	@location(1) texture_coords: vec2<f32>,
}

struct VertexOutput {
	@builtin(position) position: vec4<f32>,
	@location(0) texture_coords: vec2<f32>,
	@location(1) texture_index: u32,
}


@group(0) @binding(0)
var texture_array: binding_array<texture_2d<f32>>;
@group(0) @binding(1)
var sampler_array: binding_array<sampler>;


// INCLUDE: animate.wgsl

@vertex
fn vertex_main(
	vertex: VertexInput,
	instance: InstanceInput,
) -> VertexOutput {

	var out: VertexOutput;
	out.texture_coords = vertex.texture_coords;

	// Skip expired particles
	if instance.expires < global.current_time.x {
		out.texture_index = u32(0);
		// Draw off screen
		out.position = vec4<f32>(2.0, 2.0, 0.0, 1.0);
		return out;
	}

	let age = global.current_time.x - instance.created;

	// Apply transformations
	let rotation = mat2x2(instance.rotation_0, instance.rotation_1);
	var scale: f32 = instance.size / global.camera_zoom.x;
	var pos: vec2<f32> = vec2(vertex.position.x, vertex.position.y);
	pos = pos * vec2<f32>(
		sprites.data[instance.texture_index].aspect * scale / global.window_aspect.x,
		scale
	);
	
	pos = rotation * pos;

	var ipos: vec2<f32> = (
		vec2(instance.position.x, instance.position.y)
		+ (instance.velocity * age)
		- global.camera_position
	);

	pos = pos + vec2<f32>(
		ipos.x / (global.camera_zoom.x/2.0) / global.window_aspect.x,
		ipos.y / (global.camera_zoom.x/2.0)
	);

	out.position = vec4<f32>(pos, 0.0, 1.0);


	// Compute texture coordinates
	let t = atlas.data[animate(instance, age)];
	out.texture_index = u32(t.atlas_texture);
	out.texture_coords = vec2(t.xpos, t.ypos);
	if vertex.texture_coords.x == 1.0 {
		out.texture_coords = vec2(out.texture_coords.x + t.width, out.texture_coords.y);
	}
	if vertex.texture_coords.y == 1.0 {
		out.texture_coords = vec2(out.texture_coords.x, out.texture_coords.y + t.height);
	}

	return out;
}


@fragment
fn fragment_main(in: VertexOutput) -> @location(0) vec4<f32> {
	return textureSampleLevel(
		texture_array[in.texture_index],
		sampler_array[0],
		in.texture_coords,
		0.0
	).rgba;
}