Added bootloader

2024-12-11 18:21:07 -08:00
parent ff9dae24ff
commit 1fd7b7c55f
22 changed files with 2567 additions and 0 deletions
--- a/bootloader/linkers/x86-unknown-none.ld
+++ b/bootloader/linkers/x86-unknown-none.ld
@ -0,0 +1,57 @@
+ENTRY(start)
+OUTPUT_FORMAT(elf32-i386)
+
+SECTIONS {
+    /* The start address must match bootloader.asm */
+    . = 0x13000;
+
+    . += SIZEOF_HEADERS;
+    . = ALIGN(4096);
+
+    .text : {
+        __text_start = .;
+        *(.text*)
+        . = ALIGN(4096);
+        __text_end = .;
+    }
+
+    .rodata : {
+        __rodata_start = .;
+        *(.rodata*)
+        . = ALIGN(4096);
+        __rodata_end = .;
+    }
+
+    .data : {
+        __data_start = .;
+        *(.data*)
+        . = ALIGN(4096);
+        __data_end = .;
+        __bss_start = .;
+        *(.bss*)
+        . = ALIGN(4096);
+        __bss_end = .;
+    }
+
+    .tdata : {
+        __tdata_start = .;
+        *(.tdata*)
+        . = ALIGN(4096);
+        __tdata_end = .;
+        __tbss_start = .;
+        *(.tbss*)
+        . += 8;
+        . = ALIGN(4096);
+        __tbss_end = .;
+    }
+
+    __end = .;
+
+    /DISCARD/ : {
+        *(.comment*)
+        *(.eh_frame*)
+        *(.gcc_except_table*)
+        *(.note*)
+        *(.rel.eh_frame*)
+    }
+}